1 files changed, 56 insertions, 0 deletions
diff --git a/etc/environments/default-msvc.bat b/etc/environments/default-msvc.bat
new file mode 100644
index 0000000..40ec364
--- /dev/null
+++ b/etc/environments/default-msvc.bat
@@ -0,0 +1,56 @@
+@echo off
+
+rem file      : etc/environments/default-msvc.bat
+rem copyright : Copyright (c) 2014-2017 Code Synthesis Ltd
+rem license   : TBC; see accompanying LICENSE file
+
+rem
+rem Environment setup script for C/C++ compilation with Visual Studio 15.
+rem
+
+rem %1  - target
+rem %2  - bbot executable
+rem %3+ - bbot options
+
+setlocal EnableExtensions EnableDelayedExpansion
+
+set "MSVC=C:\Program Files (x86)\Microsoft Visual Studio\2017\Community"
+
+set "VCVARS32=%MSVC%\VC\Auxiliary\Build\vcvarsamd64_x86.bat"
+set "VCVARS64=%MSVC%\VC\Auxiliary\Build\vcvars64.bat"
+
+rem Based on target determine what we are building. If the target is
+rem not specified, then we build 64-bit by default.
+rem
+rem Note that an empty argument is passed as "" (literal quotes).
+rem
+if "_%1_" == "_x86_64-microsoft-win32-msvc14.1_" (
+  set "VCVARS=%VCVARS64%"
+) else (
+  if "_%1_" == "_i386-microsoft-win32-msvc14.1_" (
+    set "VCVARS=%VCVARS32%"
+  ) else (
+    if _%1_ == _""_ (
+      set "VCVARS=%VCVARS64%"
+    ) else (
+      echo error: unknown target %1
+      goto error
+    )
+  )
+)
+
+call "%VCVARS%"
+if errorlevel 1 goto error
+
+%2 %3 %4 %5 %6 %7 %8 %9 cc config.c=cl config.cxx=cl
+if errorlevel 1 goto error
+
+goto end
+
+:error
+@echo off
+endlocal
+exit /b 1
+
+:end
+endlocal