tests/status.test


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

# file      : tests/status.test
# copyright : Copyright (c) 2014-2017 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

.include common.test project.test

new  += 2>!
init += cc "config.cxx=$config.cxx" -d prj 2>!
sync += -d prj 2>!

: basic
:
{
  $clone_prj;
  $init -C prj-cfg @cfg &prj/build/bootstrap/*** &prj-cfg/***;

  $* >'prj configured 0.1.0-a.0.19700101000000'
}

: no-config
:
{
  $clone_prj;

  $* 2>>/"EOE" != 0
    error: no default configuration in project $~/prj/
      info: use \(@<cfg-name> | --config|-c <cfg-dir> | --all|-a\) to specify configuration explicitly
    EOE
}

: two-configs
:
{
  $clone_prj;
  $init -C prj-cfg1 @cfg1 &prj-cfg1/*** &prj/build/bootstrap/***;
  $init -C prj-cfg2 @cfg2 &prj-cfg2/***;

  $* @cfg2 >'prj configured 0.1.0-a.0.19700101000000';

  $* --all >>EOO
    in configuration @cfg1:
    prj configured 0.1.0-a.0.19700101000000

    in configuration @cfg2:
    prj configured 0.1.0-a.0.19700101000000
    EOO
}

: dependency
:
{
  $clone_prj;
  $init -C prj-cfg @cfg &prj/build/bootstrap/*** &prj-cfg/***;

  $new -t lib --vcs none libhello &libhello/***;

  cat <<EOI >+prj/repositories.manifest;
    :
    role: prerequisite
    location: ../libhello
    type: dir
    EOI

  cat <<EOI >+prj/manifest;
    depends: libhello
    EOI

  $* --recursive >>EOO 2>>/"EOE";
    prj configured 0.1.0-a.0.19700101000000 available 0.1.0-a.0.19700101000000#1
    EOO
    fetching dir:$~/libhello \(prerequisite of dir:$~/prj\)
    EOE

  $sync;

  $* --recursive >>~%EOO%
    prj configured 0.1.0-a.0.19700101000000#1
    %  libhello configured 0\.1\.0-a\.0\..+%
    EOO
}