aboutsummaryrefslogtreecommitdiff
path: root/tests/test/script/runner/cleanup.test
blob: 68d2014d7508cd3bfd496569d0f0a6767041ad7d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
# file      : tests/test/script/runner/cleanup.test
# copyright : Copyright (c) 2014-2017 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

.include ../common.test

b += --no-column

: file
:
{
  : always
  :
  $c <'$* -f a &a' && $b

  : maybe
  :
  $c <'$* &?a' && $b

  : never
  :
  $c <'$* &!a' && $b

  : implicit
  :
  : Test that a file created out of the testscript working directory is not
  : implicitly registered for cleanup. If it were, the test would fail due to
  : the file absence at the cleanup time.
  :
  $c <<EOI && $b
  touch ../../a;
  rm -f ../../a
  EOI

  : append
  :
  : Test that file append redirect does not not register cleanup. If it did,
  : that cleanup would fail as the file would be already deleted by rm.
  :
  $c <<EOI && $b
  touch a &!a;
  $* -o foo >+a;
  rm a
  EOI

  : not-exists
  :
  : Test cleanup of non-existing file.
  :
  $c <'$* &a' && $b 2>>/EOE != 0
  testscript:1: error: registered for cleanup file test/1/a does not exist
  EOE

  : out-wd
  :
  : Test explicit cleanup of a file out of the testscript working directory.
  :
  $c <'$* &../../a' && $b 2>>/EOE != 0
  testscript:1: error: file cleanup ../../a is out of working directory test/
  EOE

  : in-wd
  :
  : Test cleanup explicit registration of a file being outside the test working
  : directory but inside the script working directory.
  :
  $c <'$* &../a' && $b 2>>/EOE != 0
  testscript:1: error: registered for cleanup file test/a does not exist
  EOE

  : not-file
  :
  : Test cleanup of a directory as a file.
  :
  $c <'$* -d a &a' && $b 2>>/~%EOE% != 0
  %error: unable to remove file test/1/a: .+%
  EOE
}

: dir
:
{
  : always
  :
  $c <'$* -d a &a/' && $b

  : maybe
  :
  $c <'$* &?a/' && $b

  : implicit
  :
  : Test that a directory created out of the testscript working directory is
  : not implicitly registered for cleanup. If it were, the test would fail due
  : to the directory absence at the cleanup time.
  :
  $c <<EOI && $b
  mkdir ../../a;
  rm -r -f ../../a
  EOI

  : not-exists
  :
  : Test cleanup of non-existing directory.
  :
  $c <'$* &a/' && $b 2>>/EOE != 0
  testscript:1: error: registered for cleanup directory test/1/a/ does not exist
  EOE

  : out-wd
  :
  : Test cleanup of a directory out of the testscript working directory.
  :
  $c <'$* &../../a/' && $b 2>>/EOE != 0
  testscript:1: error: directory cleanup ../../a/ is out of working directory test/
  EOE

  : in-wd
  :
  : Test cleanup explicit registration of a directory being outside the test
  : working directory but inside the testscript working directory.
  :
  $c <'$* &../a/' && $b 2>>/EOE != 0
  testscript:1: error: registered for cleanup directory test/a/ does not exist
  EOE

  : not-empty
  :
  : Test cleanup of a non-empty directory.
  :
  {
    : files
    :
    $c <<EOI && $b 2>>/~%EOE% != 0
    $* -d a -f a/0 -f a/1 -f a/2 -f a/3 -f a/4 -f a/5 -f a/6 -f a/7 -f a/8 \
            -f a/9 -f a/a -f a/b &a/
    EOI
    testscript:2: error: registered for cleanup directory test/1/a/ is not empty
    %.%{10}
    and 2 more file(s)
    EOE

    : dir
    :
    $c <'$* -d a/b' && $b 2>>/EOE != 0
    testscript:1: error: registered for cleanup directory test/1/ is not empty
    a/
    EOE
  }

  : not-dir
  :
  : Test cleanup of a file as a directory.
  :
  $c <'$* -f a &a/' && $b 2>>/~%EOE% != 0
  %error: unable to remove directory test/1/a/: .+%
  EOE
}

: wildcard
:
{
  : self
  :
  {
    : dirs
    :
    {
      : always
      :
      $c <'$* -d a/b -d a/b/c &a/***/' && $b

      : maybe
      :
      $c <'$* &?a/***/' && $b

      : not-empty
      :
      $c <'$* -d a/b -d a/b/c -f a/c &a/***/' && $b 2>>/EOE != 0
      testscript:1: error: registered for cleanup directory test/1/a/ is not empty
      c
        info: wildcard: 'test/1/a/***/'
      EOE
    }

    : all-entries
    :
    : Test the trailing triple-star special case.
    :
    {
      : always
      :
      $c <'$* -d a1/b -f a1/b/c -d a2/b -f a2/b/c &a?/***' && $b

      : maybe
      :
      $c <'$* &?a/***' && $b

      : not-exists
      :
      : Test cleanup of a wildcard not matching any directory.
      :
      $c <'$* &a/***' && $b 2>>/EOE != 0
      testscript:1: error: registered for cleanup directory test/1/a/ does not exist
      EOE

      : out-wd
      :
      : Test cleanup of a wildcard out of the testscript working directory.
      :
      $c <'$* &../../a/***' && $b 2>>/EOE != 0
      testscript:1: error: wildcard cleanup ../../a/*** is out of working directory test/
      EOE

      : in-wd
      :
      : Test cleanup registration of a wildcard matching the directory that being
      : outside the test working directory is inside the testscript working
      : directory.
      :
      $c <'$* &../a/***' && $b 2>>/EOE != 0
      testscript:1: error: registered for cleanup directory test/a/ does not exist
      EOE

      : not-dir
      :
      : Test cleanup of a file as a wildcard.
      :
      $c <'$* -f a &a/***' && $b 2>>/~%EOE% != 0
      %error: unable to remove directory test/1/a/: .*%
      EOE
    }
  }

  : dir
  :
  {
    : always
    :
    {
      : immediate
      :
      $c <'$* -d aa/b &aa/ &a*/*/' && $b

      : recursive
      :
      $c <'$* -d aa/b/c &aa/ &a?/**/' && $b
    }

    : maybe
    :
    $c <'$* &?a/**/' && $b

    : not-exists
    :
    : Test cleanup of a wildcard that doesn't match any directory.
    :
    $c <'$* &a/**/' && $b 2>>/EOE != 0
    testscript:1: error: registered for cleanup wildcard test/1/a/**/ doesn't match any directory
    EOE

    : not-dir
    :
    : Test cleanup of a file as a directory wildcard.
    :
    $c <'$* -f a &a/**/' && $b 2>>/EOE != 0
    testscript:1: error: registered for cleanup wildcard test/1/a/**/ doesn't match any directory
    EOE

    : not-empty
    :
    : Test cleanup of a non-empty directory as a wildcard.
    :
    $c <'$* -d a/b/c -f a/b/d &a/**/' && $b 2>>/EOE != 0
    testscript:1: error: registered for cleanup directory test/1/a/b/ is not empty
    d
      info: wildcard: 'test/1/a/**/'
    EOE
  }

  : file
  :
  {
    : always
    :
    {
      : immediate
      :
      $c <'$* -d aa -f aa/c &aa/ &a?/*' && $b

      : recursive
      :
      $c <'$* -d aa/b -f aa/c -f aa/b/e &aa/ &aa/b/ &a*/**' && $b
    }

    : maybe
    :
    $c <'$* &?a/**' && $b
  }
}

: order
:
: Test that cleanup is performed in registration reversed order.
:
$c <'$* -d a/b &a/ &a/b/' && $b

: special-order
:
: Test that special files are cleaned before others, and there is no attempt
: to remove them twice (normally and with wildcard cleanup).
:
$c <<EOI && $b
$* -o foo >'foo';
$* -f bar &*
EOI

: wd-wildcard
:
: Test that there is no attempt to remove working directory twice (normally and
: with wildcard cleanup).
:
$c <<EOI && $b
true &***
EOI

: implicit-overwrite
:
: Test an implicit cleanup being overwritten with the explicit one,
:
$c <'$* -o foo >=a &!a' && $b 2>>/EOE != 0
testscript:1: error: registered for cleanup directory test/1/ is not empty
a
EOE

: explicit-overwrite
:
: Test an explicit cleanup not being overwritten with the implicit one.
:
$c <<EOO && $b 2>>/EOE != 0
$* &!a;
$* -o foo >=a
EOO
testscript:2: error: registered for cleanup directory test/1/ is not empty
a
EOE