aboutsummaryrefslogtreecommitdiff
path: root/unit-tests/cc/parser/module.testscript
blob: dc7f3e4c36696969710509f76c9488bb87359598 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
# file      : unit-tests/cc/parser/module.testscript
# copyright : Copyright (c) 2014-2019 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

# Test C++ module constructs.
#

: import
:
$* <<EOI >>EOI
import foo;
import foo.bar;
import foo.bar.baz;
EOI

: module-implementation
:
$* <<EOI >>EOI
module foo;
EOI

: module-interface
:
$* <<EOI >>EOI
export module foo;
EOI

: export-imported
:
$* <<EOI >>EOO
export import foo;
EOI
export import foo;
EOO

: export-imported-block
:
$* <<EOI >>EOO
import bar;

export {import foo;}

export
{
  namespace foo
  {
    class c {};
  }

  template <typename T> int f ();

  import bar;
}
EOI
export import bar;
export import foo;
EOO

: non-module
:
$* <<EOI
#pragma import module foo;
#pragma export module foo;
#pragma module foo;
extern module foo: int foo ();
export namespace bar {int fox ();}
EOI

: attribute
:
$* <<EOI >>EOO
import foo [[export({import})]];
module bar [[module({module})]];
EOI
import foo;
module bar;
EOO

: import-duplicate
:
$* <<EOI >>EOO
import foo;
import bar.baz;
import foo;
import bar . baz;
EOI
import foo;
import bar.baz;
EOO

: brace-missing
:
$* <<EOI 2>>EOE != 0
export
{
  class foo
  {
  //};
  module foo;
}
EOI
stdin:8:1: error: {}-imbalance detected
EOE

: brace-stray
:
$* <<EOI 2>>EOE != 0
export
{
  class foo
  {
  };}
}
module foo;
EOI
stdin:6:1: error: {}-imbalance detected
EOE

: import-missing-name
:
$* <<EOI 2>>EOE != 0
import ;
EOI
stdin:1:8: error: module name expected instead of ';'
EOE

: module-missing-name
:
$* <<EOI 2>>EOE != 0
module ;
EOI
stdin:1:1: error: module declaration expected after leading module marker
EOE

: import-missing-semi
:
$* <<EOI 2>>EOE != 0
import foo
EOI
stdin:2:1: error: ';' expected instead of <end of file>
EOE

: module-missing-semi
:
$* <<EOI 2>>EOE != 0
export module foo
EOI
stdin:2:1: error: ';' expected instead of <end of file>
EOE