tests/manifest/result.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230

# file      : tests/manifest/result.testscript
# copyright : Copyright (c) 2014-2019 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

test.options += -r

: valid
:
: Roundtrip the result manifest.
:
{
  : test-error
  :
  $* <<EOF >>EOF
  : 1
  name: libfoo
  version: 1.0
  status: error
  configure-status: success
  update-status: warning
  test-status: error
  configure-log: \
  conf line 1
  conf line 2
  \
  update-log: \
  update line 1
  update line 2
  \
  test-log: \
  test line 1
  test line 2
  \
  EOF

  : update-error
  :
  $* <<EOF >>EOF
  : 1
  name: libfoo
  version: 1.0
  status: error
  configure-status: warning
  update-status: error
  configure-log: \
  conf line 1
  conf line 2
  \
  update-log: \
  update line 1
  update line 2
  \
  EOF

  : early-abort
  :
  $* <<EOF >>EOF
  : 1
  name: libfoo
  version: 1.0
  status: abort
  EOF
}

: redefinition
:
{
  : name
  :
  $* <<EOI 2>'stdin:3:1: error: result package name redefinition' == 1
  : 1
  name: libfoo
  name: libfoo
  EOI

  : version
  :
  $* <<EOI 2>'stdin:3:1: error: result package version redefinition' == 1
  : 1
  version: 1.0
  version: 1.0
  EOI

  : status
  :
  $* <<EOI 2>'stdin:3:1: error: result status redefinition' == 1
  : 1
  status: success
  status: error
  EOI

  : configure-status
  :
  $* <<EOI 2>'stdin:4:1: error: result configure-status redefinition' == 1
  : 1
  status: success
  configure-status: success
  configure-status: abnormal
  EOI

  : configure-log
  :
  $* <<EOI 2>'stdin:5:1: error: unexpected configure-log' == 1
  : 1
  status: success
  configure-status: success
  configure-log: configured
  configure-log: configured
  EOI
}

: invalid
:
{
  : name-empty
  :
  $* <<EOI 2>'stdin:2:6: error: invalid result package name: length is less than two characters' == 1
  : 1
  name:
  EOI

  : version
  :
  {
    : empty
    :
    $* <<EOI 2>'stdin:2:9: error: invalid result package version: unexpected end' == 1
    : 1
    version:
    EOI

    : release
    :
    $* <<EOI 2>'stdin:2:10: error: invalid result package version release' == 1
    : 1
    version: 1.2.3-
    EOI
  }

  : status
  :
  $* <<EOI 2>'stdin:2:9: error: invalid result status' == 1
  : 1
  status: alert
  EOI

  : configure-status
  :
  $* <<EOI 2>'stdin:3:19: error: invalid configure-status' == 1
  : 1
  status: abort
  configure-status: alert
  EOI

  : order
  :
  {
    : op-status-before-status
    :
    $* <<EOI 2>'stdin:2:1: error: result status must appear first' == 1
    : 1
    configure-status: success
    EOI

    : op-status-after-log
    :
    $* <<EOI 2>'stdin:5:1: error: update-status after operations logs' == 1
    : 1
    status: success
    configure-status: success
    configure-log: log
    update-status: error
    EOI

    : wrong-op-log
    :
    $* <<EOI 2>'stdin:5:1: error: configure-log is expected' == 1
    : 1
    status: success
    configure-status: success
    update-status: error
    update-log: log
    EOI
  }
}

: unknown-name
:
$* <<EOI 2>"stdin:2:1: error: unknown name 'full-logs' in result manifest" == 1
: 1
full-logs: log
EOI

: missed
:
{
  : name
  :
  $* <<EOI 2>'stdin:4:1: error: no result package name specified' == 1
  : 1
  version: 1.0
  status: success
  EOI

  : version
  :
  $* <<EOI 2>'stdin:4:1: error: no result package version specified' == 1
  : 1
  name: libfoo
  status: success
  EOI

  : status
  :
  $* <<EOI 2>'stdin:4:1: error: no result status specified' == 1
  : 1
  name: libfoo
  version: 1.0
  EOI

  : configure-log
  :
  $* <<EOI 2>'stdin:6:1: error: no result configure-log specified' == 1
  : 1
  name: libfoo
  version: 1.0
  status: error
  configure-status: error
  EOI
}