aboutsummaryrefslogtreecommitdiff
path: root/tests/init.testscript
blob: 6897bc0094423ba4a77b0b4d787e3d64e34c542c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
# file      : tests/init.testscript
# license   : MIT; see accompanying LICENSE file

# Here we test both init and deinit commands.
#

.include common.testscript project.testscript

config_cxx = [cmdline] cc config.cxx=$quote($recall($cxx.path) $cxx.config.mode, true)

new    += --vcs git,branch=master
status += -d prj

: create-cfg
:
{
  +$clone_prj

  deinit += -d prj

  : with-dependency
  :
  {
    +$clone_prj

    +cat <<EOI >+prj/manifest
      depends: libprj
      EOI

    : cfg-pkg-args
    :
    {
      $clone_prj;

      $* -C @cfg $config_cxx 'config.cc.poptions=-DTEST' -- '?sys:libprj/*' 2>>/~"%EOE%" &prj-cfg/***;
        initializing in project $~/prj/
        created configuration @cfg $~/prj-cfg/ 1 target default,forwarded,auto-synchronized
        synchronizing:
        %  configure sys:libprj.*%
        %  new prj.+19700101000000%
        EOE

      sed -n -e 's/^config.cc.poptions = (.+)$/\1/p' prj-cfg/build/config.build \
        >'-DTEST';

      $status >'prj configured 0.1.0-a.0.19700101000000';

      $build prj/ 2>>~%EOE%;
        %(mkdir|c\+\+|ld|ln) .+%{4}
        EOE

      prj/prj/prj 'testscript' >'Hello, testscript!'; # Make sure is forwarded.

      $build prj-cfg/prj/ 2>>/EOE;
        info: prj-cfg/dir{prj/} is up to date
        EOE

      $build 'clean:' prj/ 2>>~%EOE%;
        %(rm|rmdir) .+%{3}
        EOE

      $deinit 2>>/"EOE"
        deinitializing in project $~/prj/
        synchronizing:
          drop prj
          drop libprj
        EOE
    }

    : cfg-pkg-args-sep
    :
    {
      $clone_prj;

      $* -C @cfg -- $config_cxx 'config.cc.poptions=-DTEST' -- '?sys:libprj/*' 2>>/~"%EOE%" &prj-cfg/***;
        initializing in project $~/prj/
        created configuration @cfg $~/prj-cfg/ 1 target default,forwarded,auto-synchronized
        synchronizing:
        %  configure sys:libprj.*%
        %  new prj.+19700101000000%
        EOE

      sed -n -e 's/^config.cc.poptions = (.+)$/\1/p' prj-cfg/build/config.build \
        >'-DTEST';

      $deinit 2>>/"EOE"
        deinitializing in project $~/prj/
        synchronizing:
          drop prj
          drop libprj
        EOE
    }

    : pkg-args
    :
    {
      $clone_prj;

      # Note that not passing the C++ configuration arguments (see above) for
      # the sake of testing, we may end up with the 'not built with default C++
      # compiler' error. To avoid this, we just make sure this is not a C++
      # project.
      #
      echo ''            >=prj/build/root.build;
      echo './: prj.cxx' >=prj/prj/buildfile;

      $* -C @cfg -- -- '?sys:libprj/*' 2>>/~"%EOE%" &prj-cfg/***;
        initializing in project $~/prj/
        created configuration @cfg $~/prj-cfg/ 1 target default,forwarded,auto-synchronized
        synchronizing:
        %  configure sys:libprj.*%
        %  new prj.+19700101000000%
        EOE

      $deinit 2>>/"EOE"
        deinitializing in project $~/prj/
        synchronizing:
          drop prj
          drop libprj
        EOE
    }
  }

  : no-module
  :
  {
    $clone_prj;

    $* -C @cfg 2>>~%EOE% != 0;
      %initializing in project .+%
      error: no build system module(s) specified for configuration to be created
        info: for example, for C/C++ configuration, specify 'cc'
        info: use '--' to create configuration without modules
        info: for example: bdep init -C ... --
      EOE

    $* -C @cfg -- 2>>/~"%EOE%" &prj-cfg/***;
      initializing in project $~/prj/
      created configuration @cfg $~/prj-cfg/ 1 target default,forwarded,auto-synchronized
      synchronizing:
      %  new prj.+19700101000000%
      EOE

    $deinit 2>>/"EOE"
      deinitializing in project $~/prj/
      synchronizing:
        drop prj
      EOE
  }
}

: add-cfg
:
{
  $clone_prj;

  deinit += -d prj;

  cat <<EOI >+prj/manifest;
    depends: libprj
    EOI

  # Pre-create configurations.
  #
  $new  -C prj-cfg1 --no-default          tmp $config_cxx 2>! &prj-cfg1/*** &tmp/***;
  $init -C prj-cfg2 --config-type host -d tmp $config_cxx 2>! &prj-cfg2/***;

  $* -A @cfg1 '?sys:libprj/*' 2>>/~"%EOE%";
    initializing in project $~/prj/
    added configuration @cfg1 $~/prj-cfg1/ 1 target default,forwarded,auto-synchronized
    synchronizing:
    %  configure sys:libprj.*%
    %  new prj.+19700101000000%
    EOE

  $* -A prj-cfg2 --no-default @cfg2 '?sys:libprj/*' 2>>/~"%EOE%";
    initializing in project $~/prj/
    added configuration @cfg2 $~/prj-cfg2/ 2 host auto-synchronized
    synchronizing:
    %  configure sys:libprj.*%
    %  new prj.+19700101000000%
    EOE

  $status --all >>EOO;
    in configuration @cfg1:
    prj configured 0.1.0-a.0.19700101000000

    in configuration @cfg2:
    prj configured 0.1.0-a.0.19700101000000
    EOO

  $build prj-cfg1/ 2>>~%EOE%;
    %(mkdir|c\+\+|ld) .+%{6}
    EOE

  $build prj-cfg2/ 2>>~%EOE%;
    %(mkdir|c\+\+|ld) .+%{6}
    EOE

  $build prj/ 2>>~%EOE%;
    %(ln|info:) .+%{2}
    EOE

  $build 'clean:' prj/ 2>>~%EOE%;
    %(rm|rmdir) .+%{3}
    EOE

  $deinit 2>>/"EOE"
    deinitializing in project $~/prj/
    synchronizing:
      drop prj
      drop libprj
    EOE
}

: pkg
:
: Test initializing a package while creating it inside an already existing
: project.
:
{
  deinit += -d prj;

  # Create (and build) the executable single-package project.
  #
  cp --no-cleanup -pr ../prj ./ &prj/***;

  $* -C @cfg $config_cxx 2>>/~"%EOE%" &prj-cfg/***;
    initializing in project $~/prj/
    created configuration @cfg $~/prj-cfg/ 1 target default,forwarded,auto-synchronized
    synchronizing:
    %  new prj.+19700101000000%
    EOE

  $status >'prj configured 0.1.0-a.0.19700101000000';

  $build prj/ 2>>~%EOE%;
    %(mkdir|c\+\+|ld|ln) .+%{4}
    EOE

  # Move the executable package into a separate directory.
  #
  mkdir --no-cleanup prj/prj.pkg;

  mv prj/prj prj/build prj/buildfile prj/manifest prj/README.md \
     prj/.gitignore prj/prj.pkg/;

  mv prj/prj.pkg prj/prj;

  cat <<EOI >=prj/packages.manifest;
    : 1
    location: prj/
    EOI

  # Add the library package.
  #
  $new --package -t lib libprj -d prj 2>>/"EOE";
    created new library package libprj in $~/prj/libprj/
    EOE

  # While at it, make sure we fail if misspell the package directory.
  #
  mkdir prj/libpr;
  $init --all -d prj/libpr 2>>/~"%EOE%" != 0;
    error: prj/libpr/ is not a package or project directory
    EOE

  $init --all -d prj/libprj 2>>/~"%EOE%";
    initializing in project $~/prj/
    synchronizing:
    %  upgrade prj.+19700101000000#1%
    %  new libprj.+19700101000000%
    EOE

  # Factor out some of the executable package functionality into the library.
  #
  cat <<EOI >+prj/prj/manifest;
    depends: libprj
    EOI

  sed -i -e 's/^(#import .+)$/import libs += libprj%lib{prj}/' \
      prj/prj/prj/buildfile;

  cat <<EOI >=prj/prj/prj/prj.cxx;
    #include <iostream>

    #include <libprj/prj.hxx>

    using namespace std;

    int main (int argc, char* argv[])
    {
      if (argc < 2)
      {
        cerr << "error: missing name" << endl;
        return 1;
      }

      prj::say_hello (cout, argv[1]);
    }
    EOI

  $build prj-cfg/prj/ 2>>/~"%EOE%";
    synchronizing $~/prj-cfg/:
    %  upgrade prj.+19700101000000#2%
    %\(mkdir|version|c\\+\\+|ld) .+%{6}
    EOE

  $deinit 2>>/"EOE"
    deinitializing in project $~/prj/
    deinitializing package prj
    deinitializing package libprj
    synchronizing:
      drop prj
      drop libprj
    EOE
}

: deinit-deorphan
:
{
  +$clone_prj

  +cat <<EOI >+prj/manifest
    depends: libprj
    EOI

  +$new -t lib -o libprj.git libprj &libprj.git/*** 2>!

  g = [cmdline] git -C libprj.git 2>! >&2

  +$g config user.name 'Test Script'
  +$g config user.email 'testscript@example.com'
  +$g add '*'
  +$g commit -m 'Create' --no-verify

  : dependency-only
  :
  {
    $clone_prj;
    cp -rp ../libprj.git ./;

    cat <<EOI >+prj/repositories.manifest;
      :
      role: prerequisite
      location: ../libprj.git#master
      EOI

    $* $config_cxx -C @cfg &prj-cfg/*** 2>!;

    git clone libprj.git &libprj/*** 2>! >&2;

    $init -d libprj -A prj-cfg 2>>/~"%EOE%";
      initializing in project $~/libprj/
      added configuration $~/prj-cfg/ 1 target default,forwarded,auto-synchronized
      %fetching .+%
      %querying .+%
      synchronizing:
      %  upgrade libprj.0.1.0-a.0.+#1%
      %  reconfigure prj.0.1.0-a.0.19700101000000%
      EOE

    $build prj/ 2>>/~%EOE%;
      %(mkdir|c\+\+|ld|ln) .+%{4}
      EOE

    $deinit -d libprj 2>>/~"%EOE%";
      deinitializing in project $~/libprj/
      %fetching dir:.+/libprj%
      %fetching dir:.+/prj%
      %fetching git:.+/libprj#.+ \\\(prerequisite of dir:.+/prj\\\)%
      querying $~/libprj.git
      synchronizing:
      %  replace.downgrade.unhold libprj.0.1.0-a.0.+%
      %  reconfigure prj.0.1.0-a.0.+%
      verifying symlinks...
      %fixing up symlinks...%?
      %distributing libprj.0.1.0-a.0.+%
      EOE

    $build prj/ 2>>/~%EOE%;
      %ln prj-cfg/prj/prj/exe\{prj\} -> prj/prj/%?
      info: prj-cfg/dir{prj/} is up to date
      EOE

    $build 'clean:' prj/ 2>>~%EOE%;
      %(rm|rmdir) .+%{3}
      EOE

    $deinit -d prj 2>>/"EOE"
      deinitializing in project $~/prj/
      synchronizing:
        drop prj
        drop libprj
      EOE
  }

  : not-only-dependency
  :
  : Similar to the above but with an additional libprj/libprj-extras library
  : which has no initialized dependents. Here we test that it is dropped while
  : being deorphaned.
  :
  {
    $clone_prj;

    $new -t empty -o libprj.git libprj &libprj.git/*** 2>!;
    $new --package -t lib libprj -d libprj.git 2>!;
    $new --package -t lib libprj-extras -d libprj.git 2>!;

    $g config user.name 'Test Script';
    $g config user.email 'testscript@example.com';
    $g add '*';
    $g commit -m 'Create' --no-verify;

    cat <<EOI >+prj/repositories.manifest;
      :
      role: prerequisite
      location: ../libprj.git#master
      EOI

    $* $config_cxx -C @cfg &prj-cfg/*** 2>!;

    git clone libprj.git &libprj/*** 2>! >&2;

    $init -d libprj -A prj-cfg 2>>/~"%EOE%";
      initializing in project $~/libprj/
      added configuration $~/prj-cfg/ 1 target default,forwarded,auto-synchronized
      initializing package libprj
      initializing package libprj-extras
      %fetching .+%
      %querying .+%
      synchronizing:
      %  upgrade libprj.0.1.0-a.0.+#1%
      %  new libprj-extras.0.1.0-a.0.+%
      %  reconfigure prj.0.1.0-a.0.19700101000000%
      EOE

    $build prj/ 2>>/~%EOE%;
      %(mkdir|c\+\+|ld|ln) .+%{4}
      EOE

    $deinit -d libprj 2>>/~"%EOE%";
      deinitializing in project $~/libprj/
      deinitializing package libprj
      deinitializing package libprj-extras
      %fetching dir:.+/libprj%
      %fetching dir:.+/prj%
      %fetching git:.+/libprj#.+ \\\(prerequisite of dir:.+/prj\\\)%
      querying $~/libprj.git
      synchronizing:
      %  drop libprj-extras.0.1.0-a.0.+ \\\(unused\\\)%
      %  replace.downgrade.unhold libprj.0.1.0-a.0.+%
      %  reconfigure prj.0.1.0-a.0.+%
      verifying symlinks...
      %fixing up symlinks...%?
      %distributing libprj.0.1.0-a.0.+%
      EOE

    $build prj/ 2>>/~%EOE%;
      %ln prj-cfg/prj/prj/exe\{prj\} -> prj/prj/%?
      info: prj-cfg/dir{prj/} is up to date
      EOE

    $build 'clean:' prj/ 2>>~%EOE%;
      %(rm|rmdir) .+%{3}
      EOE

    $deinit -d prj 2>>/"EOE"
      deinitializing in project $~/prj/
      synchronizing:
        drop prj
        drop libprj
      EOE
  }

  : not-found
  :
  {
    $clone_prj;
    cp -rp ../libprj.git ./;

    git clone libprj.git &libprj/*** 2>! >&2;

    $init $config_cxx -d libprj -C @cfg &libprj-cfg/*** 2>!;

    $* -A libprj-cfg 2>>/~"%EOE%";
      initializing in project $~/prj/
      added configuration $~/libprj-cfg/ 1 target default,forwarded,auto-synchronized
      synchronizing:
      %  new prj.0.1.0-a.0.19700101000000%
      EOE

    $build prj/ 2>>/~%EOE%;
      %(mkdir|c\+\+|ld|ln) .+%{4}
      EOE

    $deinit -d libprj 2>>/~"%EOE%" != 0;
      deinitializing in project $~/libprj/
      %fetching dir:.+/libprj%
      %fetching dir:.+/prj%
      error: libprj is not available from its dependents' repositories
      EOE

    # While at it, test that adding the repository to the dependent'
    # repositories manifest fixes the issue.
    #
    cat <<EOI >+prj/repositories.manifest;
      :
      role: prerequisite
      location: ../libprj.git#master
      EOI

    $deinit -d libprj 2>>/~"%EOE%";
      deinitializing in project $~/libprj/
      %fetching dir:.+/libprj%
      %fetching dir:.+/prj%
      %fetching git:.+/libprj#.+ \\\(prerequisite of dir:.+/prj\\\)%
      querying $~/libprj.git
      fetching from $~/libprj.git
      synchronizing:
      %  replace.unhold libprj.0.1.0-a.0.+%
      %  reconfigure prj.0.1.0-a.0.+%
      verifying symlinks...
      %fixing up symlinks...%?
      %distributing libprj.0.1.0-a.0.+%
      EOE

    $build prj/ 2>>/~%EOE%;
      %ln libprj-cfg/prj/prj/exe\{prj\} -> prj/prj/%?
      info: libprj-cfg/dir{prj/} is up to date
      EOE

    $build 'clean:' prj/ 2>>~%EOE%;
      %(rm|rmdir) .+%{3}
      EOE

    $deinit -d prj 2>>/"EOE"
      deinitializing in project $~/prj/
      synchronizing:
        drop prj
        drop libprj
      EOE
  }
}