tests/package-archive/testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127

# file      : tests/package-archive/testscript
# license   : MIT; see accompanying LICENSE file

# Note that searching for packages directly in $src_base is a bad idea, since
# removing testscript working directories while testing in source makes the
# find utility to fail with the 'no such file or directory' error. Thus, we
# clone the archives into the test working directories and search there.
#
clone_arcs = \
  cp $src_base/libhello-0.1.0.tar.gz $src_base/libhello-0.1.0+1.tar.gz ./

: pkg-verify-archive
:
{
  test.arguments += bpkg_rep_pkg_verify_archive

  : non-existing-archive
  :
  $* libhello-0.1.0.tar.gz 2>>EOE != 0
    error: archive file 'libhello-0.1.0.tar.gz' does not exist
    EOE

  : success
  :
  $* $src_base/libhello-0.1.0.tar.gz >:'libhello 0.1.0 hello'
}

: pkg-find-archives
:
{
  test.arguments += bpkg_rep_pkg_find_archives

  : none
  :
  {
    $clone_arcs;

    $* 'libhello' '0.2.0' $~
  }

  : package
  :
  {
    $clone_arcs;

    $* 'libhello' '*' $~ >>:/~"%EOO%"
      %\(
      $~/libhello-0.1.0.tar.gz
      $~/libhello-0.1.0+1.tar.gz
      %|
      $~/libhello-0.1.0+1.tar.gz
      $~/libhello-0.1.0.tar.gz
      %\)
      EOO
  }

  : package-version
  :
  {
    $clone_arcs;

    $* 'libhello' '0.1.0' $~ >:/"$~/libhello-0.1.0.tar.gz"
  }

  : package-revision
  :
  {
    $clone_arcs;

    $* 'libhello' '0.1.0+1' $~ >:/"$~/libhello-0.1.0+1.tar.gz"
  }

  : package-revisions1
  :
  {
    $clone_arcs;

    $* 'libhello' '0.1.0*' $~ >>:/~"%EOO%"
      %\(
      $~/libhello-0.1.0.tar.gz
      $~/libhello-0.1.0+1.tar.gz
      %|
      $~/libhello-0.1.0+1.tar.gz
      $~/libhello-0.1.0.tar.gz
      %\)
      EOO
  }

  : package-revisions2
  :
  {
    $clone_arcs;

    $* 'libhello' '0.1.0+2*' $~ >>:/~"%EOO%"
      %\(
      $~/libhello-0.1.0.tar.gz
      $~/libhello-0.1.0+1.tar.gz
      %|
      $~/libhello-0.1.0+1.tar.gz
      $~/libhello-0.1.0.tar.gz
      %\)
      EOO
  }
}

: pkg-find-archive
:
{
  test.arguments += bpkg_rep_pkg_find_archive

  : non-existent
  :
  $* 'libhello-0.1.0.*' $~

  : existing
  :
  {
    $clone_arcs;

    $* 'libhello-0.1.0.*' $~ >>:/"EOO"
      libhello
      0.1.0
      hello
      $~/libhello-0.1.0.tar.gz
      EOO
  }
}