tests/function/filesystem/testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123

# file      : tests/function/filesystem/testscript
# license   : MIT; see accompanying LICENSE file

.include ../../common.testscript

: path-search
:
{
  +mkdir -p a/b

  : pattern-path
  :
  : Test overloads for pattern being of the path type.
  :
  {
    : start-abs-dir
    :
    $* <'print $path_search([path] "b**/", [dir_path] $src_base/../../a)' >/'b/'

    : start-relative-dir
    :
    $* <'print $path_search([path] "b**/", [dir_path] ../../a)' 2>>~%EOE% != 0
    %error: start directory '.+' is relative%
    %  info: pattern '.+' is relative%
      <stdin>:1:8: info: while calling path_search(path, dir_path)
    EOE

    : start-untyped
    :
    $* <'print $path_search([path] "b**/", $src_base/../../a)' >/'b/'

    : start-multiple-names
    :
    $* <'print $path_search([path] "b**/", a b)' 2>>EOE != 0
    error: invalid argument: invalid dir_path value: multiple names
      <stdin>:1:8: info: while calling path_search(path, <untyped>)
    EOE
  }

  : pattern-untyped
  :
  : Test overloads for pattern being untyped.
  :
  {
    : start-dir
    :
    $* <'print $path_search("b**/", [dir_path] $src_base/../../a)' >/'b/'

    : start-untyped
    :
    $* <'print $path_search("b**/", $src_base/../../a)' >/'b/'

    : abs-pattern
    :
    if ($test.target == $build.host)
    {
      touch b;
      $* <'print $path_search("$src_base/b*")' >>/"EOO"
      $out_base/test/$@/b
      EOO
    }
  }

  : pattern-multiple-names
  :
  {
    : dir
    :
    touch b;
    $* <'print $path_search(a b, $src_base)' 2>>EOE != 0
    error: invalid argument: invalid path value: multiple names
      <stdin>:1:8: info: while calling path_search(<untyped>, dir_path)
    EOE
  }
}

: file_exists
:
{
  : file
  :
  touch f;
  $* <'print $file_exists(f)' >'true'

  : symlink
  :
  touch f && ln -s f s;
  $* <'print $file_exists([path] s)' >'true'

  : directory
  :
  mkdir d;
  $* <'print $file_exists([dir_path] d)' >'false'

  : testscript
  :
  touch f;
  echo $file_exists(f) >'true'
}

: directory_exists
:
{
  : directory
  :
  mkdir d;
  $* <'print $directory_exists(d)' >'true'

  : symlink
  :
  mkdir d && ln -s d s;
  $* <'print $directory_exists([dir_path] d)' >'true'

  : file
  :
  touch f;
  $* <'print $directory_exists([path] f)' >'false'

  : testscript
  :
  mkdir d;
  echo $directory_exists(d) >'true'
}